1 REM MAD L BOMBER
3 GOSUB 2005
4 V=53248:POKEV+21,0:POKE2042,13:BX=80:BY=30
5 SV=54296:SW=54276:SA=54277:SH=54273:SL=54272:JUMP=0:POKEV+41,7
6 PRINT"SPEED PLEASE":POKEV+4,BX:POKEV+5,BY
7 PRINT:PRINT"SUPERFAST-1":PRINT"FAST-2":PRINT"MEDIUM-3":PRINT"SLOW-4"
8 INPUT"OR SUPER SLOW-5";XP
9 IFXP=1THENSP=0
10 IFXP=2THENSP=75
11 IFXP=3THENSP=150
12 IFXP=4THENSP=300
13 IFXP=5THENSP=600
14 IFXP>5THENPRINTCHR$(147):GOTO6
15 IFXP<1THENPRINTCHR$(147):GOTO6
16 MC=0:PRINTCHR$(147)
20 IFMC>20THEN4010
21 IFMC<>10GOTO30
22 IFMC=10THENFORX=1TO4:POKE53281,1:POKE53280,1:POKE53281,0:POKE53280,0:NEXTX
23 PRINTCHR$(147):FORX=1TO7:PRINT:NEXTX
24 PRINTCHR$(18)"  VERY GOOD - YOU'RE HALF WAY THROUGH":PRINTCHR$(19):JUMP=0
25 GOSUB2031
30 TT=1 :X=0
31 FORLP=0TO2
32 POKESV,15:POKESW,33:POKESA,0:POKESH,45:POKESL,0
33 PRINTCHR$(19)"  CODE RED - MAD L BOMBER APPROACHING   ":FORLO=1TO100:NEXTLO
34 PRINTCHR$(19)CHR$(18)" CODE RED - MAD L BOMBER APPROACHING  "
35 POKESV,0:POKESW,0:POKESA,0:POKESH,0:POKESL,0:POKEV+21,4
36 FORLO=1TO40:NEXTLO:NEXT LP
37 IFK$=CHR$(X)THEN40
40 N=INT(RND(1)*38)+1
41 IFJUMP>0THENGOTO82
42 JUMP=1
50 POKE53281,0:POKE53280,0:PRINTCHR$(5);CHR$(19)
70 FOR X=0TO39:POKE1944+X,120:POKE56216+X,7:NEXTX
75 FORX=0TO3:LD=INT(RND(1)*30)+1:POKE1904+LD,102:POKE56176+LD,13
77 POKE1864+LD,92:POKE56136+LD,13:NEXTX
80 FORX=0TO5:LD=INT(RND(1)*35)+1:POKE1904+LD,102:POKE56176+LD,1:NEXTX
82 FORX=0TO39:POKE1024+X,42:POKE55296+X,12:NEXTX
94 CR=CR-40:IFCR<-800THENCR=-800
95 FORX=0TO24:LD=INT(RND(1)*35)+1
96 POKE1864+LD+CR,42:POKE56136+LD+CR,1:NEXT X
97 FORX=0TO4:LD=INT(RND(1)*35)+1
98 POKE1144+LD,42:POKE55416+LD,1:NEXT X
100 LE=INT(RND(64)*90)+1
110 IFLE<65ORLE>90GOTO100
120 GETK$:IFK$=""THEN302
130 IFK$=CHR$(LE)THEN155
140 GOTO302
155 POKESV,15:POKESW,133:POKESA,0:POKESH,0:POKESL,130
156 FOR FRY=1TO2
157 BX=BX+4:BY=BY-8:POKEV+4,BX:POKEV+5,BY
170 PRINT CHR$(13)CHR$(145)CHR$(145)TAB(N);:PRINT"/"
172 PRINT CHR$(13)CHR$(145)CHR$(145)TAB(N);:PRINTCHR$(LE):BX=BX+4:BY=BY-8
173 PRINT CHR$(13)CHR$(145)CHR$(145)TAB(N);:PRINT"-":POKEV+4,BX:POKEV+5,BY
174 PRINT CHR$(13)CHR$(145)CHR$(145)TAB(N);:PRINT"*":BX=BX+4:BY=BY-8
175 PRINT CHR$(13)CHR$(145)CHR$(145)TAB(N);:PRINTCHR$(28)".":POKEV+4,BX
176 PRINT CHR$(13)CHR$(145)CHR$(145)TAB(N);:PRINTCHR$(LE):POKEV+5,BY
178 PRINT CHR$(13)CHR$(145)CHR$(145)TAB(N);:PRINT"+":PRINTCHR$(5)
179 NEXTFRY
180 POKESV,15:POKESW,129:POKESA,15:POKESH,40:POKESL,200
182 POKEV+21,0:FORPL=1TO100:NEXTPL
185 POKESV,0:POKESW,0:POKESA,0:POKESH,0:POKESL,0
187 POKESV,15:POKESW,129:POKESA,15:POKESH,40:POKESL,200
188 POKESV,9:FORPL=1TO20:NEXTPL:POKESV,6:FORPL=1TO20:NEXTPL:POKESV,0
189 POKESW,0:POKESA,0:POKESH,0:POKESL,0
190 POKESV,15:POKESW,129:POKESA,15:POKESH,40:POKESL,200
191 FORPL=1TO350:NEXTPL
195 POKEV+21,0:POKEV+5,24:POKEV+4,60
200 POKESV,0:POKESW,0:POKESA,0:POKESH,0:POKESL,0
250 MC=MC+1:PRINTCHR$(19):BX=60:BY=60:POKEV+21,0:GOTO20
302 POKESV,15:POKESW,13:POKESA,240:POKESH,44:POKESL,0
304 POKESV,0:POKESW,0:POKESA,0:POKESH,0:POKESL,0
306 TW=INT(RND(1)*2)
308 IFTW=0THENBD=1
309 IFTW=1THENBD=-1
310 N=N+BD
311 IFN<3THENN=3
312 IFN>37THENN=37
325 PRINTCHR$(13)CHR$(145)TAB(N);:PRINTCHR$(LE)
350 FORL=1TOSP:NEXT
360 TT=TT+1:IFTT=12THEN800
370 PRINTCHR$(145)TAB(N)CHR$(28)CHR$(46):PRINTCHR$(5)
372 BX=BX+8:BY=BY+8:POKEV+4,BX:POKEV+5,BY
380 GOTO120
800 FOR BD=1TO15:POKE53281,1:POKE53280,1:POKE53281,0:POKE53280,0:NEXT
802 POKEV+21,0:POKEV+4,24:POKEV+5,60
805 PRINTCHR$(147):FORX=1TO5:PRINT:NEXT:PRINTTAB(15)"OH DEAR!!!":GOSUB1050
808 PRINTCHR$(147):FORX=1TO5:PRINT:NEXT
810 PRINTTAB(8)"YOU'LL HAVE TO BE FASTER":PRINT
811 PRINTTAB(9)"TO SAVE THE CITY FROM"
812 PRINT:PRINTTAB(7)"**** THE MAD L BOMBER ****"
814 PRINT:PRINTTAB(7)"YOU DESTROYED ";MC;" L BOMBS !":PRINTCHR$(19)
815 FORX=1TO1000:NEXTX
820 GOSUB 2031
830 PRINTCHR$(147):FORX=1TO5:PRINT:NEXT:PRINTTAB(7)"WANT TO TRY AGAIN (Y OR N)"
840 GETA$:IFA$=""THEN840
850 IFA$="Y"THENPRINTCHR$(19):GOSUB2031:CLR:GOTO4
852 IFA$="N"THEN860
854 IFA$<>"N"THEN830
860 END
1050 FORXX=35TO0STEP-.2:POKESV,XX:POKESW,129:POKESA,15:POKESH,40:POKESL,200:NEXT
1052 FORXX=35TO0STEP-.2:POKESV,XX:POKESW,129:POKESA,15:POKESH,40:POKESL,200:NEXT
1054 POKESV,0:POKESW,0:POKESA,0:POKESH,0:POKESL,0:RETURN
2005 SV=54296:SW=54276:SA=54277:SH=54273:SL=54272:V=53248
2010 PRINTCHR$(147):POKE53281,0:POKE53280,0:PRINTCHR$(5)
2020 FORPT=1TO6:PRINT:NEXT:PRINTTAB(13)"L BOMB BUSTERS "
2022 PRINT:PRINTTAB(13)"BY GARY FIELDS"
2023 PRINT:PRINTTAB(18)"1983"
2024 FORX=1TO400:NEXTX
2025 PRINT:PRINT:PRINT"YOUR MISSION IS TO SAVE THE CITY FROM"
2026 PRINTTAB(11)CHR$(18)"THE MAD L BOMBER!!"
2027 PRINT"DESTORY THE FALLING LETTER BOMBS BY"
2028 PRINT"PRESSING THE SAME KEY ON THE KEYBOARD":FORX=1TO1000:NEXTX
2029 PRINTCHR$(19):FORPR=0TO63:READPQ:POKE832+PR,PQ:NEXTPR
2031 FORDL=0TO500:NEXTDL
2035 FORL=0TO24:POKESL+L,0:NEXT
2040 POKESL+14,5:POKESL+18,16:POKESL+3,1:POKESL+24,143:POKESL+6,240:POKESL+4,65
2050 FR=5389
2060 FORFT=1TO50:FQ=FR+PEEK(SL+27)*3.5
2070 HF=INT(FQ/256):LF=FQ-HF*256:POKESL+0,LF:POKESL+1,HF
2075 PRINTTAB(10)"L BOMBS ARE FALLING":NEXT:POKESL+24,0
2080 PRINTCHR$(147):RETURN
4010 PRINTCHR$(147):FORX=1TO5:PRINT:NEXT:PRINTTAB(10)"VERY GOOD FAST FINGERS"
4012 PRINTTAB(16)"-YOU WIN-":PRINT:PRINT
4014 PRINTTAB(7)"YOU BURST ALL ";MC;" L BOMBS"
4015 PRINT:PRINT"THE HAPPY PEOPLE OF THE CITY THANK YOU !"
4040 FORL=0TO24:POKESL+L,0:NEXT:POKESL+0,240:POKESL+1,33:POKESL+5,8
4050 POKESL+22,104:POKESL+23,1:POKESL+24,79:FORN=1TO19:POKESL+4,129
4060 FORXT=1TO100:NEXT:POKESL+4,128:FORXT=1TO30:NEXT:NEXT
4065 POKESL+22,0:POKESL+33,0:POKESL+24,0:POKESL+4,0
4067 POKESL+1,0:POKESL+0,0:POKESL+1,0:POKESL+5,0:POKESL+22,0:POKESL+23,0
4068 POKESL+33,0
4069 FORX=0TO999:NEXTX
4070 GOTO830
6000 DATA0,0,0,0,0,0,0,0,0,0,0,0,0,0,0, 0
6001 DATA0,0,0,0,0,0,12,0,128,30,64,199,152,32,224, 218
6002 DATA32,176,108,38,184,127,33,143,255,248,255,254,29,254,0, 28
6003 DATA7,255,157,3,255,248,1,255,193,0,0,6,0,0,0, 0